|
這個(gè)是VB的代碼，自己新建一個(gè)ActiveX DLL，然后改變工程名稱(chēng)和類(lèi)名稱(chēng)，然后在類(lèi)中輸入如下內(nèi)容即可。
'//////////////////////////////
'中文名稱(chēng)：INI文件操作類(lèi)
'英文名稱(chēng)：Blood_INI Class
'作者：Blood
'制作時(shí)間：2002.2.8
'版本：1.0
'版權(quán)所有 Blood 2002-2003
'//////////////////////////////
'申明變量
Private strAppName As String'INI小節(jié)名稱(chēng)
Private strKeyName As String'INI項(xiàng)目名
Private strValueStr As String 'INI的項(xiàng)目值
Private strFileName As String 'INI文件名
'申明操作INI文件的API
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As String, ByVal lpFileName As String) As Long
'////////////////////
'開(kāi)始定義函數(shù)
'////////////////////
'定義寫(xiě)INI文件的函數(shù)
Public Function WriteINI() As Long
'通過(guò)API將值寫(xiě)入INI文件
WriteINI = WritePrivateProfileString(strAppName, strKeyName, strValueStr, strFileName)
End Function
'定義讀INI文件的函數(shù)
Public Function GetINI() As String
Const STRING_SIZE = 255 '指定字符串長(zhǎng)度
Dim lngLength As Long '定義API函數(shù)返回的長(zhǎng)度
Dim strDefault As String * STRING_SIZE'定義在沒(méi)有找到指定的項(xiàng)目時(shí)返回的默認(rèn)值
Dim strReturn As String * STRING_SIZE '定義一個(gè)字符串緩沖區(qū)
'通過(guò)API函數(shù)取得INI文件的內(nèi)容
lngLength = GetPrivateProfileString(strAppName, strKeyName, strDefault, strReturn, STRING_SIZE, strFileName)
'通過(guò)判斷API函數(shù)返回的長(zhǎng)度來(lái)確定返回的值
If (lngLength = 0) Then
GetINI = strValueStr
Else
GetINI = Mid(strReturn, 1, lngLength)
End If
End Function
'////////////////////
'定義函數(shù)結(jié)束
'////////////////////
'////////////////////
'開(kāi)始定義屬性
'////////////////////
'取得INI文件的名稱(chēng)
Public Property Let FileName(ByVal strFile As String)
strFileName = strFile
End Property
'取得項(xiàng)目值
Public Property Let ValueStr(ByVal strValue As String)
strValueStr = strValue
End Property
'取得項(xiàng)目名稱(chēng)
Public Property Let KeyName(ByVal strKey As String)
strKeyName = strKey
End Property
'取得小節(jié)名稱(chēng)
Public Property Let AppName(ByVal strApp As String)
strAppName = strApp
End Property
'////////////////////
'結(jié)束定義屬性
'////////////////////
|
