本講將使用到ADSI，即活動(dòng)目錄服務(wù)接口.可以到15Seconds.com找到一些相關(guān)的資料.

1.創(chuàng)建用戶
下面這段代碼在獨(dú)立服務(wù)器white上創(chuàng)建用戶user1,初始口令user1,用到了ADSI.
Dim Username,UserPass
Dim oDomain,oUser
Username = "user1"
UserPass = "user1"
Set oDomain = GetObject("WinNT://white")
Set oUser = oDomain.Create ("user", UserName)
If (err.number = 0) Then
oUser.SetInfo
oUser.SetPassword UserPass
oUser.SetInfo
Else
WScript.Echo "創(chuàng)建用戶" & UserName & "出錯(cuò)！"
End If
Set oUser = Nothing
Set oDomain = Nothing

2.創(chuàng)建目錄
使用FileSystemObject創(chuàng)建目錄:
Dim FsObject
Dim tmpFolder
Set FsObject = WScript.CreateObject("Scripting.FileSystemObject")
tmpFolder = "D:\userdate\user1"
If Not FsObject.FolderExists(tmpFolder) Then
FsObject.CreateFolder(tmpFolder)
If Err.Number<>0 Then
WScript.Echo "創(chuàng)建目錄" & tmpFolder & "失��！"
End If
End If
注意在創(chuàng)建目錄前,先檢查了目錄是否存在,如果存在,則不用創(chuàng)建了.

3.創(chuàng)建站點(diǎn)
下面這個(gè)子程序負(fù)責(zé)創(chuàng)建一個(gè)WWW站點(diǎn),各個(gè)參數(shù)的意義為：站點(diǎn)IP地址,站點(diǎn)根目錄,站點(diǎn)說明,主機(jī)名,端口號(hào),計(jì)算機(jī)名(一搬為LOCALHOST),是否立即啟動(dòng),匿名訪問時(shí)所使用的帳號(hào),匿名訪問時(shí)所用帳號(hào)的口令,LOG文件的目錄.
函數(shù)返回所建站點(diǎn)在IIS中的序號(hào)(在IIS中,所有站點(diǎn)依次編號(hào),第一個(gè)為1).
一個(gè)調(diào)用示例：siteid = ASTCreateWebSite("10.1.3.122","d:\userdata\user1","www_user1","","80","LocalHost",True,"IUSR_user1","8iui%#","D:\Logfiles")

Function ASTCreateWebSite(IPAddress, RootDirectory, ServerComment, HostName, PortNum, Computer, Start,AnonymousUserName,AnonymousUserPass,LogFileDirectory)
Dim w3svc, WebServer, NewWebServer, NewDir
Dim Bindings, BindingString, NewBindings, Index, SiteObj, bDone
On Error Resume Next
Err.Clear
Set w3svc = GetObject("IIS://" & Computer & "/w3svc")
If Err.Number <> 0 Then
WScript.Echo "無法打開: "&"IIS://" & Computer & "/w3svc" & VbCrlf & "程序?qū)⑼顺?"
WScript.Quit (1)
End If

BindingString = IpAddress & ":" & PortNum & ":" & HostName
For Each WebServer in w3svc
If WebServer.Class = "IIsWebServer" Then
Bindings = WebServer.ServerBindings
If BindingString = Bindings(0) Then
WScript.Echo "IP地址沖突:" & IpAddress & ",請檢測IP地址！." & VbCrlf & "取消創(chuàng)建本站點(diǎn)。"
Exit Function
End If
End If
Next

Index = 1
bDone = False

While (Not bDone)
Err.Clear
Set SiteObj = GetObject("IIS://"&Computer&"/w3svc/" & Index)
If (Err.Number = 0) Then
Index = Index + 1
Else
Err.Clear
Set NewWebServer = w3svc.Create("IIsWebServer", Index)
If (Err.Number <> 0) Then
Index = Index + 1
Else
Err.Clear
Set SiteObj = GetObject("IIS://"&Computer&"/w3svc/" & Index)
If (Err.Number = 0) Then
bDone = True
Else
Index = Index + 1
End If
End If
End If

If (Index > 10000) Then
WScript.Echo "看起來不能創(chuàng)建站點(diǎn)，正在創(chuàng)建的站點(diǎn)的序號(hào)為： "&Index&"." & VbCrlf & "取消創(chuàng)建本站點(diǎn)。"
Exit Function
End If
Wend

NewBindings = Array(0)
NewBindings(0) = BindingString
NewWebServer.ServerBindings = NewBindings
NewWebServer.ServerComment = ServerComment
NewWebServer.AnonymousUserName = AnonymousUserName
NewWebServer.AnonymousUserPass = AnonymousUserPass
NewWebServer.KeyType = "IIsWebServer"
NewWebServer.FrontPageWeb = True
NewWebServer.EnableDefaultDoc = True
NewWebServer.DefaultDoc = "Default.htm, Default.asp, Index.htm, Index.asp"
NewWebServer.LogFileDirectory = LogFileDirectory
NewWebServer.SetInfo

Set NewDir = NewWebServer.Create("IIsWebVirtualDir", "ROOT")
NewDir.Path = RootDirectory
NewDir.AccessRead = true
NewDir.AppFriendlyName = "應(yīng)用程序" & ServerComment
NewDir.AppCreate True
NewDir.AccessScript = True
Err.Clear
NewDir.SetInfo
If (Err.Number = 0) Then
Else
WScript.Echo "主目錄創(chuàng)建時(shí)出錯(cuò)."
End If

If Start = True Then
Err.Clear
Set NewWebServer = GetObject("IIS://" & Computer & "/w3svc/" & Index)
NewWebServer.Start
If Err.Number <> 0 Then
WScript.Echo "啟動(dòng)站點(diǎn)時(shí)出錯(cuò)!"
Err.Clear
Else
End If
End If
ASTCreateWebSite = Index
End Function

下面函數(shù)創(chuàng)建ＦＴＰ站點(diǎn)：
Function ASTCreateFtpSite(IPAddress, RootDirectory, ServerComment, HostName, PortNum, Computer, Start,LogFileDirectory)
Dim MSFTPSVC, FtpServer, NewFtpServer, NewDir
Dim Bindings, BindingString, NewBindings, Index, SiteObj, bDone
On Error Resume Next
Err.Clear
Set MSFTPSVC = GetObject("IIS://" & Computer & "/MSFTPSVC")
If Err.Number <> 0 Then
WScript.Echo "無法打開: "&"IIS://" & Computer & "/MSFTPSVC" & VbCrlf & "程序?qū)⑼顺?"
WScript.Quit (1)
End If

BindingString = IpAddress & ":" & PortNum & ":" & HostName
For Each FtpServer in MSFTPSVC
If FtpServer.Class="IIsFtpServer" Then
Bindings = FtpServer.ServerBindings
If BindingString = Bindings(0) Then
WScript.Echo "IP地址沖突:" & IpAddress & ",請檢測IP地址！." & VbCrlf & "取消創(chuàng)建本站點(diǎn)。"
Exit Function
End If
End If
Next

Index = 1
bDone = False

While (Not bDone)
Err.Clear
Set SiteObj = GetObject("IIS://"&Computer&"/MSFTPSVC/" & Index)
If (Err.Number = 0) Then
Index = Index + 1
Else
Err.Clear
Set NewFtpServer = MSFTPSVC.Create("IIsFtpServer", Index)
If (Err.Number <> 0) Then
Index = Index + 1
Else
Err.Clear
Set SiteObj = GetObject("IIS://"&Computer&"/MSFTPSVC/" & Index)
If (Err.Number = 0) Then
bDone = True
Else
Index = Index + 1
End If
End If
End If

If (Index > 10000) Then
WScript.Echo "看起來不能創(chuàng)建站點(diǎn)，正在創(chuàng)建的站點(diǎn)的序號(hào)為： "&Index&"." & VbCrlf & "取消創(chuàng)建本站點(diǎn)。"
Exit Function
End If
Wend

NewBindings = Array(0)
NewBindings(0) = BindingString
NewFtpServer.ServerBindings = NewBindings
NewFtpServer.ServerComment = ServerComment
NewFtpServer.AllowAnonymous = False
NewFtpServer.AccessWrite = True
NewFtpServer.AccessRead = True
NewFtpServer.DontLog = False
NewFtpServer.LogFileDirectory = LogFileDirectory
NewFtpServer.SetInfo

Set NewDir = NewFtpServer.Create("IIsFtpVirtualDir", "ROOT")
NewDir.Path = RootDirectory
NewDir.AccessRead = true
Err.Clear
NewDir.SetInfo
If (Err.Number = 0) Then
Else
WScript.Echo "主目錄創(chuàng)建時(shí)出錯(cuò)."
End If

If Start = True Then
Err.Clear
Set NewFtpServer = GetObject("IIS://" & Computer & "/MSFTPSVC/" & Index)
NewFtpServer.Start
If Err.Number <> 0 Then
WScript.Echo "啟動(dòng)站點(diǎn)時(shí)出錯(cuò)!"
Err.Clear
Else
End If
End If
ASTCreateFtpSite = Index
End Function