讀取文件
要從文本文件讀取數(shù)據(jù)，則使用 TextStream 對象的 Read、ReadLine 或 ReadAll 方法。下表描述了不同的任務應使用哪種方法。
任務 方法
從文件讀取指定數(shù)量的字符。 Read
讀取一整行（一直到但不包括新行字符）。 ReadLine
讀取文本文件的整個內(nèi)容。 ReadAll


如果使用 Read 或 ReadLine 方法，并且想跳過數(shù)據(jù)的特殊部分，則使用 Skip 或 SkipLine 方法。read 方法的結(jié)果文本存在一個字符串中，該字符串可以顯示在一個控件中，也可以用字符串函數(shù)（如 Left、Right 和 Mid）來分析，連接等等。

下面的 VBScript 示例示范了如何打開文件，和如何寫數(shù)據(jù)到文件中并從文件讀取數(shù)據(jù)：


Sub ReadFiles
Dim fso, f1, ts, s
Const ForReading = 1
Set fso = CreateObject("Scripting.FileSystemObject")
Set f1 = fso.CreateTextFile("c:\testfile.txt", True)
' 寫一行。
Response.Write "Writing file <br>"
f1.WriteLine "Hello World"
f1.WriteBlankLines(1)
f1.Close
' 讀取文件的內(nèi)容。
Response.Write "Reading file <br>"
Set ts = fso.OpenTextFile("c:\testfile.txt", ForReading)
s = ts.ReadLine
Response.Write "File contents = '" & s & "'"
ts.Close
End Sub

下面的代碼示范了在 JScript 中做同樣的事：

function ReadFiles()
{
var fso, f1, ts, s;
var ForReading = 1;
fso = new ActiveXObject("Scripting.FileSystemObject");
f1 = fso.CreateTextFile("c:\\testfile.txt", true);
// 寫一行。
Response.Write("Writing file <br>");
f1.WriteLine("Hello World");
f1.WriteBlankLines(1);
f1.Close();
// 讀取文件的內(nèi)容。
Response.Write("Reading file <br>");
ts = fso.OpenTextFile("c:\\testfile.txt", ForReading);
s = ts.ReadLine();
Response.Write("File contents = '" + s + "'");
ts.Close();
}

移動、復制和刪除文件
FSO 對象模式各有兩種方法移動、復制和刪除文件，如下表所述。

任務方法
移動文件File.Move 或 FileSystemObject.MoveFile
復制文件File.Copy 或 FileSystemObject.CopyFile
刪除文件File.Delete 或 FileSystemObject.DeleteFile


下面的 VBScript 示例，在驅(qū)動器 C 的根目錄中創(chuàng)建一個文本文件，向其中寫一些信息，然后把它移動到 \tmp 目錄中，并在 \temp 中做一個備份，最后把它們從兩個目錄中刪掉。

要運行下面的示例，需要先在驅(qū)動器 C 的根目錄中創(chuàng)建 \tmp 和 \temp 目錄：


Sub ManipFiles
Dim fso, f1, f2, s
Set fso = CreateObject("Scripting.FileSystemObject")
Set f1 = fso.CreateTextFile("c:\testfile.txt", True)
Response.Write "Writing file <br>"
' 寫一行。
f1.Write ("This is a test.")
' 關(guān)閉文件。
f1.Close
Response.Write "Moving file to c:\tmp <br>"
' 獲取 C 的根目錄(C:\)中的文件的句柄。
Set f2 = fso.GetFile("c:\testfile.txt")
' 把文件移動到 \tmp 目錄。
f2.Move ("c:\tmp\testfile.txt")
Response.Write "Copying file to c:\temp <br>"
' 把文件復制到 \temp 目錄。
f2.Copy ("c:\temp\testfile.txt")
Response.Write "Deleting files <br>"
' 獲得文件當前位置的句柄。
Set f2 = fso.GetFile("c:\tmp\testfile.txt")
Set f3 = fso.GetFile("c:\temp\testfile.txt")
' 刪除文件。
f2.Delete
f3.Delete
Response.Write "All done!"
End Sub

下面的代碼示范了在 JScript 中做同樣的事：

function ManipFiles()
{
var fso, f1, f2, s;
fso = new ActiveXObject("Scripting.FileSystemObject");
f1 = fso.CreateTextFile("c:\\testfile.txt", true);
Response.Write("Writing file <br>");
// 寫一行。
f1.Write("This is a test.");
// 關(guān)閉文件。
f1.Close();
Response.Write("Moving file to c:\\tmp <br>");
// 獲取 C 的根目錄(C:\)中的文件的句柄。
f2 = fso.GetFile("c:\\testfile.txt");
// 把文件移動到 \tmp 目錄。
f2.Move ("c:\\tmp\\testfile.txt");
Response.Write("Copying file to c:\\temp <br>");
// 把文件復制到 \temp 目錄。
f2.Copy ("c:\\temp\\testfile.txt");
Response.Write("Deleting files <br>");
// 獲得文件當前位置的句柄。
f2 = fso.GetFile("c:\\tmp\\testfile.txt");
f3 = fso.GetFile("c:\\temp\\testfile.txt");
// 刪除文件。
f2.Delete();
f3.Delete();
Response.Write("All done!");
}